PROJECT( aggfontfreetype )

CMAKE_MINIMUM_REQUIRED( VERSION 3.13 )

FIND_PACKAGE( Freetype REQUIRED MODULE )

SET( font_freetype_HEADERS
    agg_font_freetype.h
)


ADD_LIBRARY( ${PROJECT_NAME} STATIC
    ${font_freetype_HEADERS}
    agg_font_freetype.cpp)

TARGET_INCLUDE_DIRECTORIES(${PROJECT_NAME}
PUBLIC
    $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>
    $<INSTALL_INTERFACE:include/${PROJECT_NAME}>
)

SET_TARGET_PROPERTIES(
    ${PROJECT_NAME}
    PROPERTIES
    PUBLIC_HEADER "${font_freetype_HEADERS}"
    VERSION ${agg_VERSION}
    SOVERSION 0.${agg_VERSION}
)

TARGET_LINK_LIBRARIES( ${PROJECT_NAME} PUBLIC Freetype::Freetype agg )
TARGET_COMPILE_DEFINITIONS( ${PROJECT_NAME} PUBLIC AGG_USE_FREETYPE )

ADD_LIBRARY( agg::fontfreetype ALIAS ${PROJECT_NAME} )
TARGET_LINK_LIBRARIES( agg_internal INTERFACE agg::fontfreetype )

INSTALL(TARGETS ${PROJECT_NAME}
    EXPORT aggTargets DESTINATION ${CMAKE_INSTALL_LIBDIR}
    RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR} COMPONENT runtime
    ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR} COMPONENT devel
    PUBLIC_HEADER DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/agg/fontfreetype COMPONENT devel
)
